;***********************************************************************;
;*        P c D F S  : PC DISK FILING SYSTEM VOOR DE ELECTRON          *;
;*---------------------------------------------------------------------*;
;*    module         : Sidewayrom service calls                        *;
;*---------------------------------------------------------------------*;
;*    filenaam       : service.inc                                     *;
;*    auteur         : Roland Leurs                                    *;
;*                     The Atomic Development Studio                   *;
;*    ontwikkeld     : juli 1996                                       *;
;*    laatste update :                                                 *;
;*---------------------------------------------------------------------*;
;*    assembleren    : als include opnemen in PCDFS.ASM                *;
;*---------------------------------------------------------------------*;
;*    oproep         : -                                               *;
;***********************************************************************;

service         cmp #$18                ; test op ondersteunde reason code
                bcs reason00            ; spring indien code niet ondersteund
                asl a                   ; verdubbel reason code nummer
                tax                     ; zet in index register
                lda reasons,x           ; lees beginadres uit tabel
                sta zp                  ; zet in werkruimte
                lda reasons+1,x
                sta zp+1
                jmp (zp)                ; voer call uit

reason00        rts

reasons         dw reason00,reason00,reason00,reason03
                dw reason00,reason00,reason00,reason00
                dw reason00,reason00,reason00,reason00
                dw reason00,reason00,reason00,reason00
                dw reason00,reason00,reason00,reason00
                dw reason00,reason00,reason00,reason00

reason03        ; reason code $03: auto-boot call
                jsr init_transfer       ; initialiseer communicatie
                ldx #0                  ; stuur controle string naar pc
reason03_l1     lda controletext,x      ; lees karakter
                jsr zendbyte            ; stuur naar pc
                inx                     ; verhoog pointer
                cmp #0                  ; test op einde tekst
                bne reason03_l1         ; spring indien nog tekens volgen
                php                     ; save processor status
                sei                     ; blokkeer interrupts
                ldx #13                 ; laadt index
reason03_l2     lda fs_tab,x            ; laadt byte uit vector tabel
                sta $212,x              ; schrijf vector
                dex                     ; verlaag index
                bpl reason03_l2         ; spring indien nog bytes volgen
                plp                     ; herstel processor status/interrupts
                rts

controletext    .db 12,15               ; scherm schoon en page mode uit
                .db "PcDFS host ready " ; tekst
                .db 0                   ; einde tekst

fs_tab          .dw osfile, osargs, osbget, osbput
                .dw osgbpb, osfind, osfsc